The Question

What can you infer about someone’s social network from their text messaging activity?

A few months ago, I started working on an app that syncs text messages from an Android phone to a desktop client for the Mac. The idea was to decouple text messaging from the phone, enabling the user to have a conversation anywhere and seamlessly transition between messaging on the phone and messaging on a laptop or desktop.

While developing the application, I noticed that the thousands of messages synced by the app revealed interesting trends about my conversational patterns, and it seemed like a perfect data set for a visualization. But what? I drew up a bunch ideas on paper, and a few stuck with me.

Idea 1: A wavestream visualization of the number of messages sent and received from certain contacts, over time.

Idea 2: A spring graph network with bubbles representing different contacts that you message. Size, distance from spindle used to represent relative frequency of messaging…

The Data

The application downloads all the user’s messages from their phone and stores them in an SQLite database. A text dump from this database formed the data used in the visualization. The format of the text dump is shown below:

6157141096:::Allison:::1:::119:::87

The text is ‘:::’ delimited. The columns are as follows:

  1. The phone number messaged
  2. The display name of the user messaged
  3. The origin of the message (0 = your phone, 1 = theirs)
  4. The frame number on which the message should appear in the animation. This is calculated by taking the timestamp of when the message was sent or received, subtracting the timestamp of the first message in the animation and dividing by an acceleration factor.
  5. The length of the text content in the message.

The Visualization

The Discoveries

The biggest discovery along the way was that Processing is pretty cool and very easy to use. I have a lot of experience working with OpenGL and Mac OS X’s Quartz2D APIs, and Processing was a nice surprise. I was able to go from concept to an early working version of the visualization in one afternoon. My one big complaint is that there’s no built-in debugger whatsoever… Coming from a programming background, that’s pretty damn ghetto. I’ve heard you can use Eclipse somehow, so I’ll try that next time.

I was unsure of how to create a graph of interconnected nodes in Processing. I wanted to create one dynamically without advance knowledge of the number of nodes needed, and I didn’t want to write any code to do it. I thought that using some sort of spring physics model would allow the graph to be self-organizing. I did some searching and found the Traer Physics library, which I dropped into my Processing libraries folder and linked into my sketch by binding each contact object to a node in the physics simulation. That was it. There was much rejoicing.

Each node was added to the physics model as a solid body, and negative attractors were added between each of the nodes to cause them to spread evenly. Springs were added between each node and the center ring. This turned out to be a great solution because the resting length of the spring could be adjusted to move the nodes toward and away from the center. I’d wanted to do this the whole time, but using the springs allowed me to smoothly animate that part of the visualization, too.

My original idea was to represent each message sent or received as an arc between nodes. However, I wasn’t sure whether Processing would be able to handle drawing the number of curves required at a decent framerate. With a data set of over 2300 messages, I was pretty sure it would become unworkably slow. Big surprise, it’s Java, and it did. I had to add a shortcut to disable lines so I could rapidly test the visualization.

The Critique

Overall, I’m pretty happy with the visualization. I was able to animate it, and it achieved the initial goal of revealing the social network inferred by your messaging habits. There are a few things I’d like to explore in the data that the visualization doesn’t reveal, though. There’s a lot of data in the actual text contents of the messages that would be fun to look at. How often do people use emoticons? Do you use emoticons more frequently when the person you’re talking to also does? Is there a bimodal distribution in message length that implies that some messages are part of complex multi-message conversations while others are simple “pings?” Answering those questions would require other visualizations, I think–but I’m really curious.

The Code

Dependencies: The processing applet requires the Traer Physics library.

Example Code Used: The code below draws on a large amount of sample code, from Processing.org and from the documentation of the Traer Physics Library. The Processing “Load File 2″ example was particularly useful. The code for the wavestream was written from scratch (in a rather ghetto way.) I’m still looking for a good library that creates them!

The source code is available here

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
 
import traer.physics.*;
 
import java.util.Date;
 
import java.text.SimpleDateFormat;
 
import java.lang.Long;
 
 
 
static int RECENT_FRAME_COUNT = 50;
 
 
 
boolean drawLines;
 
boolean simulationComplete;
 
boolean useCharacterCounts;
 
 
 
String[] lines;
 
int index = 0;
 
ArrayList messages;
 
int firstUnusedMessageIndex;
 
ArrayList contacts;
 
Contact me;
 
float mostMessagesInContact;
 
 
 
long timestamp;
 
int timestampsPerFrame;
 
int frameNumber;
 
int framesInSimulation;
 
 
 
int timeBeforeDecay = 150;
 
 
 
ParticleSystem system;
 
 
 
void setup() {
 
  size(900, 900);
 
  background(0);
 
  stroke(255);
 
  smooth();
 
 
 
  lines = loadStrings("/sms.txt");
 
  firstUnusedMessageIndex = 0;
 
  messages = new ArrayList();
 
  contacts = new ArrayList();
 
 
 
  frameNumber = 0;
 
  framesInSimulation = 0;
 
 
 
  drawLines = true;
 
  simulationComplete = false;
 
  useCharacterCounts = true;
 
  frameRate(60);
 
 
 
  system = new ParticleSystem();
 
  system.setIntegrator(ParticleSystem.RUNGE_KUTTA);
 
  system.setDrag(0.5);
 
 
 
  timestamp = Long.parseLong(lines[0]);
 
  timestampsPerFrame = 10;
 
  index ++;
 
 
 
  while (index < lines.length) {
 
    String[] pieces = split(lines[index], ":::");
 
    if (pieces.length > 1) {
 
      messages.add(new SMS(pieces));
 
      println(lines[index]);
 
      // Go to the next line for the next run through draw()
 
    }
 
    index = index + 1;
 
  }
 
  println("loaded "+messages.size() + " messages");
 
 
 
  HashMap hm = new HashMap();
 
  for (int ii = 0; ii < messages.size(); ii ++) {
 
    SMS m = (SMS)messages.get(ii);
 
    if (hm.containsKey(m.phoneNumber)) {
 
      int count = int((Integer)(hm.get(m.phoneNumber)));
 
      hm.put(m.phoneNumber, new Integer(count + 1));
 
    } 
 
    else
 
      hm.put(m.phoneNumber, new Integer(1));
 
  }
 
 
 
  Iterator i = hm.entrySet().iterator();  // Get an iterator
 
  mostMessagesInContact = 0;
 
  while (i.hasNext()) {
 
    Map.Entry me = (Map.Entry)i.next();
 
    int v = int((Integer)me.getValue());
 
    if (v > mostMessagesInContact)
 
      mostMessagesInContact = v;
 
  }
 
 
 
  framesInSimulation = ((SMS)messages.get(messages.size() - 1)).timestamp;
 
 
 
  me = new Contact("ME", "ME", width / 2, height / 2 + 50);
 
  me.root.makeFixed();
 
  me.radius = 20;
 
  contacts.add(me);
 
}
 
 
 
void mouseClicked() {
 
  drawLines = !drawLines;
 
}
 
 
 
void keyPressed() {
 
  useCharacterCounts = !useCharacterCounts;
 
}
 
 
 
void draw() {
 
  fill(0,0,0);
 
  noStroke();
 
  rect(0, 100, width, height);
 
  rect(0, 0, width/3+1, height/3);
 
  rect(width - 100, 0, 100, 41);
 
  fill(255, 60, 60);
 
  rect(20, 20, 30, 20);
 
  fill(60, 255, 60);
 
  rect(20, 50, 30, 20);
 
  fill(255,255,255);
 
  if (useCharacterCounts) {
 
    text("Volume of Text Sent To",55, 65);
 
    text("Volume of Text Received From",55, 35);
 
  } 
 
  else { 
 
    text("Messages Sent To",55, 65);
 
    text("Messages Received From",55, 35);
 
  }
 
  text(firstUnusedMessageIndex + " / " + messages.size(),20, 900-30);
 
 
 
  Date d = new Date(timestamp);
 
  SimpleDateFormat dateformatMMDDYYYY = new SimpleDateFormat("MM/dd/yyyy");
 
  text(dateformatMMDDYYYY.format(d), width-100,35);
 
 
 
  float wavestreamStepPerFrame = float(width * 2/3) / float(framesInSimulation);
 
  println(wavestreamStepPerFrame);
 
  int wavestreamX = int(frameNumber * wavestreamStepPerFrame) + width / 3;
 
  float wavestreamCenterY = 60;
 
  float wavestreamSmoothing = 0.95;
 
 
 
  float accumulatedSent = 0;
 
  float accumulatedReceived = 0;
 
 
 
  for (int ii = 0; ii < contacts.size(); ii++) {
 
    Contact c = (Contact)contacts.get(ii);
 
 
 
    // determine the height of this bar of the wavestream
 
    float r = 0;
 
    for (int x = 0; x < RECENT_FRAME_COUNT; x ++)
 
      r += c.messagesSentInRecentFrames[x] * 0.7f;
 
 
 
    c.sentVelocity = (float)c.sentVelocity * wavestreamSmoothing + (r - c.messagesSentAvg) * (float)(1-wavestreamSmoothing);
 
    c.messagesSentAvg = c.messagesSentAvg * wavestreamSmoothing + c.sentVelocity * (1-wavestreamSmoothing);
 
 
 
    // pick a random color for this person
 
    stroke(80,255,80);
 
    //stroke((212 * ii) % 255, (190 * ii) % 255, (123 * ii) % 255);
 
    line(wavestreamX, wavestreamCenterY + accumulatedSent, wavestreamX, wavestreamCenterY + accumulatedSent + c.messagesSentAvg);
 
    accumulatedSent += c.messagesSentAvg;
 
 
 
    r = 0;
 
    for (int x = 0; x < RECENT_FRAME_COUNT; x ++)
 
      r += c.messagesReceivedInRecentFrames[x] * 0.7f;
 
 
 
    stroke(255,80,80);
 
    c.receivedVelocity = (float)c.receivedVelocity * wavestreamSmoothing + (r - c.messagesReceivedAvg) * (float)(1-wavestreamSmoothing);
 
    c.messagesReceivedAvg = c.messagesReceivedAvg * wavestreamSmoothing + c.receivedVelocity * (1-wavestreamSmoothing);
 
 
 
    line(wavestreamX, wavestreamCenterY - accumulatedReceived, wavestreamX, wavestreamCenterY - accumulatedReceived - c.messagesReceivedAvg);
 
    accumulatedReceived += c.messagesReceivedAvg;
 
  }
 
 
 
 
 
  for (int ii = 0; ii < firstUnusedMessageIndex; ii++) {
 
    SMS s = (SMS)messages.get(ii);
 
    s.draw();
 
    s.update();
 
  }
 
 
 
  for (int ii = 0; ii < contacts.size(); ii++) {
 
    Contact c = (Contact)contacts.get(ii);
 
    c.draw();
 
    c.update();
 
  }
 
 
 
 
 
  for (int ii = 0; ii < contacts.size(); ii++) {
 
    Contact c = (Contact)contacts.get(ii);
 
    if ((mouseX > c.x - c.radius) && (mouseX < c.x + c.radius) && (mouseY > c.y - c.radius) && (mouseY < c.y + c.radius)) {
 
      c.drawHoverLabel();
 
    }
 
  }
 
 
 
  system.tick();
 
  frameNumber += timestampsPerFrame;
 
 
 
  if (!simulationComplete)
 
    timestamp = timestamp + (1000*1000)*10;
 
 
 
  boolean found = true;
 
  while (found == true) {
 
    if (firstUnusedMessageIndex >= messages.size()) {
 
      simulationComplete = true;
 
      break;
 
    }
 
 
 
    SMS m = (SMS)messages.get(firstUnusedMessageIndex);
 
    if (m.timestamp < frameNumber) {
 
      // the message has been sent this frame! figure out if we need to 
 
      // create the contact object that represents it. 
 
      Contact c = contactForPhoneNumber(m.phoneNumber);
 
 
 
      if (c == null) {
 
        c = new Contact(m.phoneNumber, m.name, width / 2 + random(-300, 300), height / 2 + random(-300, 300));
 
        contacts.add(c);
 
      }
 
 
 
      // are we starting at the contact and going to ME or the other way around?
 
      if (m.origin == 0) {
 
        m.source = me;
 
        m.notme = c;
 
        m.destination = c;
 
      } 
 
      else {
 
        m.source = c;
 
        m.notme = c;
 
        m.destination = me;
 
      }
 
 
 
      // make it so the other contact is pulled toward us just a bit more. They're more
 
      // improtant in my life.
 
      c.relationshipSpring.setRestLength(max(c.radius + 25, 0.99 * c.relationshipSpring.restLength()));
 
 
 
      // let the message initialize it's state
 
      m.prepareForAnimation();
 
      firstUnusedMessageIndex ++;
 
    } 
 
    else {
 
      found = false;
 
      break;
 
    }
 
  }
 
  //saveFrame();
 
}
 
 
 
Contact contactForPhoneNumber(String phoneNumber) {
 
  for (int ii = 0; ii < contacts.size(); ii++)
 
    if (((Contact)contacts.get(ii)).phoneNumber.equals(phoneNumber))
 
      return (Contact)contacts.get(ii);
 
  println("Couldn't find contact with pn = "+phoneNumber);
 
  return null;
 
}
 
 
 
 
 
class SMS {
 
  int origin;
 
  String phoneNumber;
 
  String name;
 
  int timestamp;
 
  int charcount;
 
 
 
  // only set once the SMS has been spawned
 
  Contact source;
 
  Contact destination;
 
  Contact notme;
 
  float x,y, destRadOffset, destROffset;
 
  float cx, cy;
 
  float fraction;
 
  float radius = 4;
 
  int age;
 
 
 
  public SMS(String[] pieces) {
 
    phoneNumber = pieces[0];
 
    name = pieces[1];
 
    origin = int(pieces[2]);
 
    timestamp = int(pieces[3]);
 
    charcount = int(pieces[4]);
 
  }
 
 
 
  public void prepareForAnimation() {
 
    x = source.x;
 
    y = source.y;
 
    destRadOffset = random(0, 360);
 
    destROffset = random(0,1);
 
    cx = random(-190, 190);
 
    cy = random(-190, 190);
 
  }
 
 
 
  public void draw() {
 
    noFill();
 
    if (drawLines) {
 
      int b = max(30, 255-age);
 
      if (origin == 0)
 
        stroke(b/3,b,b/3);
 
      else
 
        stroke(b,b/3,b/3);
 
 
 
      float destOffsetX = cos(destRadOffset) * destROffset * notme.radius;
 
      float destOffsetY = sin(destRadOffset) * destROffset * notme.radius;
 
      curve(me.x, me.y, me.x, me.y, notme.x + destOffsetX, notme.y + destOffsetY, notme.x + cx, notme.y + cy);
 
    }
 
    if (fraction < 1) {
 
      fill(255,255,255);
 
      noStroke();
 
      ellipse(x,y, radius * 2, radius * 2);
 
    }
 
  }
 
 
 
  public void update() {
 
    if (!simulationComplete)
 
      age ++;
 
 
 
    if (fraction < 1) {
 
      fraction += 0.1;
 
      if (fraction >= 1) {
 
        notme.wasMessaged(origin, charcount);
 
      }
 
      x = source.x * fraction + destination.x * (1-fraction);
 
      y = source.y * fraction + destination.y * (1-fraction);
 
    }
 
  }
 
}
 
 
 
class Contact {
 
  String phoneNumber;  
 
  String name;
 
  float x,y;
 
  float radius;
 
  Particle root;
 
  Spring relationshipSpring;
 
  int framesSinceMessage;
 
 
 
  int messagesSent;
 
  int messagesReceived;
 
  int[] messagesSentInRecentFrames;
 
  int[] messagesReceivedInRecentFrames;
 
  float messagesSentAvg; 
 
  float messagesReceivedAvg; 
 
  float sentVelocity;
 
  float receivedVelocity;
 
 
 
  int charsSent;
 
  int charsReceived;
 
 
 
  public Contact(String pn, String n, float x, float y) {
 
    radius = 6;
 
    phoneNumber = pn;
 
    name = n;
 
    framesSinceMessage = 0;
 
    root = system.makeParticle(1, x, y, 0);
 
    messagesSentInRecentFrames = new int[RECENT_FRAME_COUNT];
 
    messagesReceivedInRecentFrames = new int[RECENT_FRAME_COUNT];
 
 
 
    for (int ii = 0; ii < contacts.size(); ii++)
 
      system.makeAttraction(root, ((Contact)contacts.get(ii)).root, -3, 5);
 
 
 
    if (pn.equals("ME") == false)
 
      relationshipSpring = system.makeSpring(root, me.root, 0.05, 0.8, 350);
 
  }
 
 
 
  public void draw() {
 
    noStroke();  
 
    if (this != me) {
 
      int b = max(50, 255-framesSinceMessage);
 
 
 
      fill(b,b,b);
 
      ellipse(x,y,radius*2,radius*2);
 
 
 
      if (messagesReceived + messagesSent > 0) {
 
        float receivedAngle;
 
        float sentAngle;
 
        if (useCharacterCounts) {
 
          receivedAngle = (charsReceived / (float)(charsReceived + charsSent)) * (2 * PI);
 
          sentAngle = (charsSent / (float)(charsReceived + charsSent)) * (2 * PI);
 
        } 
 
        else {
 
          receivedAngle = (messagesReceived / (float)(messagesReceived + messagesSent)) * (2 * PI);
 
          sentAngle = (messagesSent / (float)(messagesReceived + messagesSent)) * (2 * PI);
 
        }
 
 
 
        float innerRadius = max(radius * 1.5, radius * 2 - 5);
 
        fill(b, b/3, b/3);
 
        arc(x,y, innerRadius,innerRadius, -PI / 2, -PI / 2 + receivedAngle);
 
        fill(b/3, b, b/3);
 
        arc(x,y, innerRadius,innerRadius, -PI / 2 + receivedAngle, -PI / 2 + receivedAngle + sentAngle);
 
      }
 
    }
 
    else {
 
      fill(255,255,255);
 
      ellipse(x,y,radius*2,radius*2);
 
      fill(0,0,0);
 
      ellipse(x,y,radius*1.5,radius*1.5);
 
    }
 
  }
 
 
 
  public void drawHoverLabel() {
 
    String s = name + " ("+phoneNumber+")";
 
    fill(0);
 
    text(s, x+9, y+11);
 
    fill(0);
 
    text(s, x+11, y+11);
 
    fill(0);
 
    text(s, x+9, y+9);
 
    fill(0);
 
    text(s, x+11, y+9);
 
    fill(255,255,255);
 
    text(s, x+10, y+10);
 
  }
 
 
 
  public void update() {
 
    if (!simulationComplete)
 
      framesSinceMessage ++;
 
    x = root.position().x();
 
    y = root.position().y();
 
 
 
    if ((framesSinceMessage > timeBeforeDecay) && (relationshipSpring != null))
 
      relationshipSpring.setRestLength(min(350, 1.005 * relationshipSpring.restLength()));
 
 
 
    for (int ii = RECENT_FRAME_COUNT - 2; ii >= 0; ii--) {
 
      messagesReceivedInRecentFrames[ii + 1] = messagesReceivedInRecentFrames[ii];
 
      messagesSentInRecentFrames[ii + 1] = messagesSentInRecentFrames[ii];
 
    }
 
    messagesReceivedInRecentFrames[0] = 0;
 
    messagesSentInRecentFrames[0] = 0;
 
  }
 
 
 
  public void wasMessaged(int origin, int charcount) {
 
    radius = radius + 0.25 * (300.0 / mostMessagesInContact);
 
    root.setMass(root.mass() + 0.25);
 
    framesSinceMessage = 0;
 
 
 
    if (origin == 0) {
 
      messagesSent ++;
 
      charsSent += charcount;
 
      messagesSentInRecentFrames[0] ++;
 
    } 
 
    else {
 
      messagesReceived ++;
 
      charsReceived += charcount;
 
      messagesReceivedInRecentFrames[0] ++;
 
    }
 
  }
 
}

A note about source data: Unfortunately, the source data for this experiment contains sensitive data including people’s phone numbers and names. I’ll be releasing the SMS synchronizing app for Mac and Android soon and that will allow you to gather and format your own messaging history for visualization.